如何在 Haskell 中连接变量参数？

Shell-monad 支持可变参数 https://hackage.haskell.org/package/shell-monad-0.6.9/docs/Control-Monad-Shell.html#t:CmdParams，但是我找不到一种方法来传递此类参数的列表以进行追加。可能可以使用该库中存在的函数构造来解决问题，但我想问一下一般问题。

我模糊地理解“varargs”机制是通过函数组合实现的，并且通过使用类型类推断来终止递归。

以该库为例，我想知道是否可以将参数视为“第一类”，例如将两个参数分配给一个变量。

这是一个（不正确的）示例，显示了我的意图。

Prelude Control.Monad.Shell Data.Text> f xs = cmd "cat" xs
Prelude Control.Monad.Shell Data.Text> let a = static ("a" :: Text)
Prelude Control.Monad.Shell Data.Text> let a2 = [a,a]
Prelude Control.Monad.Shell Data.Text> f a2

<interactive>:42:1: error:
    • Could not deduce (Param [Term Static Text])
        arising from a use of ‘f’
      from the context: CmdParams t2
        bound by the inferred type of it :: CmdParams t2 => t2
        at <interactive>:42:1-4
    • In the expression: f a2
      In an equation for ‘it’: it = f a2

没有什么是一点多态递归不能解决的：

cmdList :: (Param command, Param arg, CmdParams result) =>
    command -> [arg] -> result
cmdList command = go . reverse where
    go :: (Param arg, CmdParams result) => [arg] -> result
    go [] = cmd command
    go (arg:args) = go args arg

在 ghci 中尝试一下：

> Data.Text.Lazy.IO.putStr . script $ cmdList "cat" ["dog", "fish"]
#!/bin/sh
cat dog fish

它需要给出的所有参数cmdList具有相同的类型，尽管它仍然接受之后不以列表形式存在的其他类型的附加参数。

如果您愿意打开扩展程序，您甚至可以让它接受多个位置的列表，每个位置可能有不同的类型。

list :: (Param arg, CmdParams result) =>
    (forall result'. CmdParams result => result') ->
    [arg] -> result
list f [] = f
list f (arg:args) = list (f arg) args

使用它的一个例子：

> T.putStr . script $ list (list (cmd "cat") ["dog", "fish"] "bug") ["turtle", "spider"]
#!/bin/sh
cat dog fish bug turtle spider

以前的cmdList可以定义为cmdList command = list (cmd command). (N.B. cmdList = list . cmd does not work!)

接受包含不同类型的列表会产生更多噪音，但对于存在类型来说是可能的。

data Exists c where Exists :: c a => a -> Exists c

elist :: CmdParams result =>
    (forall result. CmdParams result => result) ->
    [Exists Param] -> result
elist f [] = f
elist f (Exists arg:args) = elist (f arg) args

但看看使用起来有多么烦人：

> T.putStr . script $ elist (cmd "cat") [Exists "dog", Exists "fish"]
#!/bin/sh
cat dog fish

以前的list可以通过它来定义list f = elist f . map Exists.