Subversion Hook 的常见类型

人们在 Subversion 中使用什么类型的钩子脚本？只是一般想法，但代码也很棒！

我正在使用pre-revprop-change钩子允许我在执行提交后实际返回并编辑注释和此类信息。如果提交注释中缺少/错误信息，这非常有用。

这里我发一个pre-revprop-change.batWindows NT 或更高版本的批处理文件。你 当然可以通过更多修改来增强它。您还可以导出一个post-revprop-change.cmd从它备份旧的snv:log某处或只是将其附加到新日志中。

唯一棘手的部分是能够实际解析标准输入 批处理文件。这是在这里完成的FIND.EXE命令。

另一件事是，我收到了其他用户关于使用/b与exit命令。你可能只需要删除它/b在您的特定应用程序中，如果错误情况表现不佳。

@ECHO OFF

set repos=%1
set rev=%2
set user=%3
set propname=%4
set action=%5

::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
:: Only allow changes to svn:log. The author, date and other revision
:: properties cannot be changed
::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
if /I not '%propname%'=='svn:log' goto ERROR_PROPNAME

::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
:: Only allow modifications to svn:log (no addition/overwrite or deletion)
::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
if /I not '%action%'=='M' goto ERROR_ACTION

::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
:: Make sure that the new svn:log message contains some text.
::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
set bIsEmpty=true
for /f "tokens=*" %%g in ('find /V ""') do (
 set bIsEmpty=false
)
if '%bIsEmpty%'=='true' goto ERROR_EMPTY

goto :eof



:ERROR_EMPTY
echo Empty svn:log properties are not allowed. >&2
goto ERROR_EXIT

:ERROR_PROPNAME
echo Only changes to svn:log revision properties are allowed. >&2
goto ERROR_EXIT

:ERROR_ACTION
echo Only modifications to svn:log revision properties are allowed. >&2
goto ERROR_EXIT

:ERROR_EXIT
exit /b 1