为什么将开放数组参数转换为数组类型会导致 E2089 无效类型转换？

我在用着德尔福2007（预泛型）并且我定义了许多可用于所有数组的函数TObject的后代，例如：

function IndexOf(AArray : array of TObject; AItem : TObject) : integer;
begin
  //...
end;

用于向它们传递动态数组TObject的后代，我定义了一个数组类型TObjectArray = array of TObject。通过这种方式，我可以转换动态数组并将它们传递给我的函数，没有任何问题：

type
  TChild = class(TObject);

...

procedure Test();
var
  Items : array of TChild;
  Item : TChild;
begin
  //...
  IndexOf(TObjectArray(Items), Item);
end;

当我尝试向它们传递开放数组参数时，问题就出现了：

procedure  Test(AItems : array of TChild);
var
  Item : TChild;
begin
  //...
  IndexOf(TObjectArray(AItems), Item);
end;

在这些情况下，编译器会引发以下错误消息：

E2089 无效的类型转换

为什么会发生这种情况以及如何避免这种情况？

将任何类型的数组传递给开放数组参数时，无需进行类型转换，前提是元素类型相同。您可以按原样传递数组，开放数组将很好地接受它。这就是开放数组的全部意义。

type
  TChild = class(TObject);

...

function IndexOf(AArray : array of TObject; AItem : TObject) : integer;
begin
  //...
end;

procedure Test();
var
  Items : array of TObject;
  Item : TChild;
begin
  //...
  IndexOf(Items, Item);
end;

procedure Test2();
var
  Items : array[0..N] of TObject;
  Item : TChild;
begin
  //...
  IndexOf(Items, Item);
end;

procedure Test3(AItems : array of TObject);
var
  Item : TChild;
begin
  //...
  IndexOf(AItems, Item);
end;

但是，您不能传递数组TChild其中数组TObject是期待。编译器将拒绝它并显示“不兼容类型”错误。输入数组必须使用与开放数组相同的元素类型。

当传递动态数组或固定数组时，一个简单的类型转换可以解决这个问题：

procedure Test();
type
  TObjectArray = array of TObject;
var
  Items : array of TChild;
  Item : TChild;
begin
  //...
  IndexOf(TObjectArray(Items), Item);
end;

procedure Test2();
type
  TObjectFixedArray = array[0..N] of TObject;
  PObjectFixedArray = ^TObjectFixedArray;
var
  Items : array[0..N] of TChild;
  Item : TChild;
begin
  //...
  IndexOf(PObjectFixedArray(@Items)^, Item);
end;

但是，您根本无法将开放数组类型转换为任何其他数组类型。不同类型的数组具有不同的内存布局（将动态数组类型转换为另一个动态数组，或将固定数组转换为另一个固定数组，不会更改正在类型转换的数组的内存布局）。

在开放数组的情况下，它实际上根本不是一个数组，它只是指向所传递数组的第一个元素的指针，并且还有第二个隐藏参数用于数组长度。换句话说，这种声明：

procedure Test3(AItems : array of TChild);

实际上是由编译器在幕后实现的，如下所示：

procedure Test3(AItems : ^TChild; AItems_High: Integer);

因此，您必须将打开的数组元素复制到另一个数组，然后传递该数组：

procedure Test3(AItems : array of TChild);
var
  Items: array of TObject;
  Item : TChild;
  I: Integer;
begin
  //...
  SetLength(Items, Length(AItems));
  For I := Low(AItems) to High(AItems) do
    Items[I] := AItems[I];
  IndexOf(Items, Item);
end;