使用量化约束导出 Ord（forall a.Ord a => Ord (f a)）

通过量化的约束我可以得出Eq (A f)正好？但是，当我尝试导出 Ord (A f) 时，它失败了。我不明白当约束类具有超类时如何使用量化约束。我如何得出Ord (A f)以及其他有超类的类？

> newtype A f = A (f Int)
> deriving instance (forall a. Eq a => Eq (f a)) => Eq (A f)
> deriving instance (forall a. Ord a => Ord (f a)) => Ord (A f)
<interactive>:3:1: error:
    • Could not deduce (Ord a)
        arising from the superclasses of an instance declaration
      from the context: forall a. Ord a => Ord (f a)
        bound by the instance declaration at <interactive>:3:1-61
      or from: Eq a bound by a quantified context at <interactive>:1:1
      Possible fix: add (Ord a) to the context of a quantified context
    • In the instance declaration for 'Ord (A f)'

附言。我也检查过ghc 提案 0109-量化-约束 https://github.com/ghc-proposals/ghc-proposals/blob/master/proposals/0109-quantified-constraints.rst#superclasses。使用 ghc 8.6.5

问题是Eq是一个超类Ord，以及约束(forall a. Ord a => Ord (f a))不涉及超类约束Eq (A f)需要声明一个Ord (A f)实例。

• We have (forall a. Ord a => Ord (f a))

• We need Eq (A f), i.e., (forall a. Eq a => Eq (f a))，这并不是我们所拥有的暗示。

解决办法：添加(forall a. Eq a => Eq (f a)) to the Ord实例。

（我实际上不明白 GHC 给出的错误消息与问题有何关系。）

{-# LANGUAGE QuantifiedConstraints, StandaloneDeriving, UndecidableInstances, FlexibleContexts #-}

newtype A f = A (f Int)
deriving instance (forall a. Eq a => Eq (f a)) => Eq (A f)
deriving instance (forall a. Eq a => Eq (f a), forall a. Ord a => Ord (f a)) => Ord (A f)

或者更整洁一点：

{-# LANGUAGE ConstraintKinds, RankNTypes, KindSignatures, QuantifiedConstraints, StandaloneDeriving, UndecidableInstances, FlexibleContexts #-}

import Data.Kind (Constraint)

type Eq1 f = (forall a. Eq a => Eq (f a) :: Constraint)
type Ord1 f = (forall a. Ord a => Ord (f a) :: Constraint)  -- I also wanted to put Eq1 in here but was getting some impredicativity errors...

-----

newtype A f = A (f Int)
deriving instance Eq1 f => Eq (A f)
deriving instance (Eq1 f, Ord1 f) => Ord (A f)