Unity3D - 用于精灵裁剪的着色器

我正在尝试创建一个可用于在游戏中剪辑 2D 精灵的着色器，我在中找到了该着色器另一个问题 https://stackoverflow.com/questions/16397023/unity3d-a-shader-that-will-clip-a-texture-on-ios-device

Shader "Sprites/ClipArea"
{
Properties
{
    _MainTex ("Base (RGB), Alpha (A)", 2D) = "white" {}
    _Length ("Length", Range(0.0, 1.0)) = 1.0
    _Width ("Width", Range(0.0, 1.0)) = 0.5
 }

SubShader
{
    LOD 200

    Tags
    {
        "Queue" = "Transparent"
        "IgnoreProjector" = "True"
        "RenderType" = "Transparent"
    }

    Pass
    {
        Cull Off
        Lighting Off
        ZWrite Off
        Offset -1, -1
        Fog { Mode Off }
        ColorMask RGB
        Blend SrcAlpha OneMinusSrcAlpha

        CGPROGRAM
        #pragma vertex vert
        #pragma fragment frag

        #include "UnityCG.cginc"

        sampler2D _MainTex;
        float4 _MainTex_ST;
        float _Length;
        float _Width;

        struct appdata_t
        {
            float4 vertex : POSITION;
            float2 texcoord : TEXCOORD0;
        };

        struct v2f
        {
            float4 vertex : POSITION;
            float2 texcoord : TEXCOORD0;
        };

        v2f vert (appdata_t v)
        {
            v2f o;
            o.vertex = mul(UNITY_MATRIX_MVP, v.vertex);
            o.texcoord = v.texcoord;
            return o;
        }

        half4 frag (v2f IN) : COLOR
        {
            if ((IN.texcoord.x<0) || (IN.texcoord.x>_Width) || (IN.texcoord.y<0) || (IN.texcoord.y>_Length))

            {
                half4 colorTransparent = half4(0,0,0,0) ;
                return  colorTransparent ;
            }
            return tex2D(_MainTex, IN.texcoord);
        }
        ENDCG
    }
}
}

它在单个精灵上完美工作，但我使用的是由 Unity Sprite 编辑器划分的精灵表。

着色器中的 _Width 变量覆盖了整个精灵表，而不是我正在处理的精灵。我寻找一种方法来获取着色器内的当前精灵矩形，但找不到任何东西。

好吧，在拉扯我的头发三天后，我设法找到了解决方法。 在搜索更多有关着色器如何工作以及在管道中的作用之后，我意识到精灵矩形信息可能在着色器中不可用，原因很简单，几乎所有着色器（除了我的）的功能都不需要此信息，因为着色器的工作是获取一个顶点，通过顶点函数修改其位置（如果需要），然后通过片段函数决定其像素颜色，所以它不关心整个精灵，它只需要查找像素使用纹理坐标从纹理中获取特定顶点的颜色。 我确信这对于使用着色器的人来说是微不足道的信息，但我花了一些时间才意识到这一点（这是我的第一个着色器）。 因此，作为一种解决方法，我必须使用着色器属性来传递着色器正在精灵表中处理的当前精灵的 MinX 和 MaxX，因此着色器现在如下所示：

Shader "Sprites/ClipArea"
{
    Properties
    {
        _MainTex ("Base (RGB), Alpha (A)", 2D) = "white" {}
        _Fill ("Fill", Range(0.0, 1.0)) = 1.0
        _MinX ("MinX", Float) = 0
        _MaxX ("MaxX", Float) = 1
     }

    SubShader
    {
        LOD 200

        Tags
        {
            "Queue" = "Transparent"
            "IgnoreProjector" = "True"
            "RenderType" = "Transparent"
        }

        Pass
        {
            Cull Off 
            Lighting Off
            ZWrite Off
            Offset -1, -1
            Fog { Mode Off }
            ColorMask RGB
            Blend SrcAlpha OneMinusSrcAlpha

            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag

            #include "UnityCG.cginc"

            sampler2D _MainTex;
            float4 _MainTex_ST;
            float _MinX;
            float _MaxX;
            float _Fill;

            struct appdata_t
            {
                float4 vertex : POSITION;
                float2 texcoord : TEXCOORD0; 
            };

            struct v2f
            {
                float4 vertex : POSITION;
                float2 texcoord : TEXCOORD0;
            };

            v2f vert (appdata_t v)
            {
                v2f o;
                o.vertex = mul(UNITY_MATRIX_MVP, v.vertex);
                o.texcoord = v.texcoord;
                return o;
            }

            half4 frag (v2f IN) : COLOR 
            {
            if ((IN.texcoord.x<_MinX)|| (IN.texcoord.x>(_MinX+_Fill*(_MaxX-_MinX))))
                {
                    half4 colorTransparent = half4(0,0,0,0) ;
                    return  colorTransparent ;
                }
                return tex2D(_MainTex, IN.texcoord);
            }
            ENDCG
        }
    }
} 

要使用此着色器，您需要创建一个使用它的材质，然后在 SpriteRenderer 中使用该材质，您可以从检查器中更改 Fill amount、MinX 和 MaxX，或者调用 spriteRenderer.material.setFloat(property, value ）来自代码。

然后我遇到了动画精灵的另一个问题，我必须在每一帧上不断更新 MinX 和 MaxX，但是当我在更新函数中执行此操作时，动画开始闪烁，那是因为在渲染精灵后调用更新，所以我必须使用主相机 OnPreRender 事件来更新材质属性。

也许有更好的方法来实现这一切，但这是我能想到的最好的方法，我希望这能让那些试图达到相同效果的人受益。